← Foro de Visual Basic

Anular el boton de inicio y la taskBar con un api usando de sist op win2000 o xp

Hilo en el foro de Visual Basic · 10 de Marzo del 2004 · 1 respuestas
KlausD10 de Marzo del 2004
Pregunta
Hola , buen dia .
alguien sabe como puedo hacer para anular la taskbar
con windows 2000 o xp .
probe varios codigos pero no funccionaron,
ahhh y a los que dicen que el ctr alt del en xp o 2000 no se puede anular , estan equivocados yo vi alguien que lo inutizo en brasil usando vb pero no quiso compartir el codigo.

saludos

Respuestas 1

en?10 de Marzo del 2004
Lo hemos comprobado en w98SE y wXP, y funciona.


Para hacer la prueba pega esto en un form con un CommandButton:

Option Explicit

Private Enum TipoAccion
SW_HIDE = &H0 ' Ocultar
SW_SHOW = &H5 ' Mostrar
End Enum

Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWndParent As Long, ByVal hWndChildAfter As Long, _
ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindow Lib "user32" _
Alias "FindWindowA" (ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long
Private Declare Function ShowWindow Lib "user32" _
(ByVal hWnd As Long, ByVal nCmdShow As Long) As Long

Private Sub ShowHideTaskBar(ByVal Accion As TipoAccion)
Dim pTr As Long

pTr = FindWindow("Shell_TrayWnd", vbNullString)
If pTr = 0 Then Exit Sub

If Accion = SW_HIDE Then ShowWindow pTr, SW_HIDE Else ShowWindow pTr, SW_SHOW
End Sub

Private Sub Command1_Click()
Static Oculta As Boolean

If Oculta Then ShowHideTaskBar SW_SHOW Else ShowHideTaskBar SW_HIDE

Oculta = Not Oculta
End Sub


Un saludo.
¿Buscas más hilos como este? Mira el foro de Visual Basic o usa el buscador.