Necesito Ayuda para un marcador telefonico

c4rlos
11 de Noviembre del 2003
Bueno ante que todo les quiero perdir que me puedan ayudar en lo que necesito.

Quiero realizar un sistema que realice llamadas telofonicas, pero que lo hago solo. el sistema debe hacer la llamda cuando ocurra un evento externo al sistema.
ejemplo: imaginen un sitema de seguridad para el hogar, si esta sola mi casa, de ocurrir que se encienda una alarma el pc me haga una llamada a mi telefono movil.

sin mas que decir, les agradeceria en todo lo que me puedan ayudar.

mi correo es [email protected] si me escribe ahi es muhco mejor.



DoloresMot
11 de Noviembre del 2003
Inserta este codigo en una forma. Antes debes de crear un boton llamado "DialButton"
Debes de insertar el componente Mscomm32.ocx a tu proyecto. Lo puede insertar en la opcion Projectcomponents o (Ctrl+T) alli lo encuentras.
Private Sub Dial(Number$)
Dim DialString$, FromModem$, dummy

' AT is the Hayes compatible ATTENTION command and is required to send commands to the modem.
' DT means "Dial Tone." The Dial command uses touch tones, as opposed to pulse (DP = Dial Pulse).
' Numbers$ is the phone number being dialed.
' A semicolon tells the modem to return to command mode after dialing (important).
' A carriage return, vbCr, is required when sending commands to the modem.
DialString$ = "ATDT" + Number$ + ";" + vbCr

' Communications port settings.
' Assuming that a mouse is attached to COM1, CommPort is set to 2
MSComm1.CommPort = 2
MSComm1.Settings = "9600,N,8,1"

' Open the communications port.
On Error Resume Next
MSComm1.PortOpen = True
If Err Then
MsgBox "COM2: not available. Change the CommPort property to another port."
Exit Sub
End If

' Flush the input buffer.
MSComm1.InBufferCount = 0

' Dial the number.
MSComm1.Output = DialString$

' Wait for "OK" to come back from the modem.
Do
dummy = DoEvents()
' If there is data in the buffer, then read it.
If MSComm1.InBufferCount Then
FromModem$ = FromModem$ + MSComm1.Input
' Check for "OK".
If InStr(FromModem$, "OK") Then
' Notify the user to pick up the phone.
Beep
MsgBox "Please pick up the phone and either press Enter or click OK"
Exit Do
End If
End If

' Did the user choose Cancel?
If CancelFlag Then
CancelFlag = False
Exit Do
End If
Loop

' Disconnect the modem.
MSComm1.Output = "ATH" + vbCr

' Close the port.
MSComm1.PortOpen = False
End Sub

Private Sub DialButton_Click()
Dim Number$, Temp$

DialButton.Enabled = False
QuitButton.Enabled = False
CancelButton.Enabled = True

' Get the number to dial.
Number$ = InputBox$("Enter phone number:", Number$)
If Number$ = "" Then Exit Sub
Temp$ = Status
Status = "Dialing - " + Number$

' Dial the selected phone number.
Dial Number$

DialButton.Enabled = True
QuitButton.Enabled = True
CancelButton.Enabled = False

Status = Temp$
End Sub

Suerte.