c_sosa
08 de Noviembre del 2003

como puedo guardar y recuperar informacion de un archivo de texto
agradesco la ayuda

Ken
08 de Noviembre del 2003

Prueba con las funciones a bajo nivel:
*!* -
*!*
*!* TextToFile( pcTexto, pcArchivo ) --> -1, 0, 1
*!*
*!* Crea y graba en "pcArchivo" el contenido de "pcTexto"
*!*
*!* -
Function TextToFile
Parameter pcTexto, pcArchivo
Local nManejador
nManejador = FCreate( pcArchivo, 0 )
If nManejador = -1 Then
Return 0
EndIf

If FWrite( nManejador, pcTexto ) = 0 Then
FClose(nManejador)
Return -1
EndIf

FClose(nManejador)
Return 1
EndFunc


*!* -
*!*
*!* FileToText( pcArchivo ) --> cTexto
*!*
*!* Lee de "pcArchivo" y devuelve su contenido, pero solo hará si:
*!* exista dicho archivo
*!* se pueda abrir (no esté bloquedo)
*!* Longitud no sea mayor a 256 letras (bytes)
*!*
*!* -
Function FileToText
Parameter pcArchivo
Local nManejador, nTamaño, cTexto
If File(pcArchivo) = .F. Then
Return ""
EndIf

nManejador = FOpen( pcArchivo, 0 )
If nManejador = -1 Then
Return ""
EndIf

nTamaño = FSeek( nManejador, 0, 2 ) && Lleva el puntero a EoF
If nTamaño <= 0 Then
cTexto = "" && Si el archivo está vacío...
Else
*!* Si el archivo no está vacío, se almacena su contenido en memoria
= FSeek( nManejador, 0, 0 )
cTexto = FRead( nManejador, nTamaño )
EndIf

FClose( nManejador ) && Cierra el archivo
Return cTexto
EndFunc

-------------------
Suerte
Ken Torrealba
El Callao - Venezuela

Luisen98
08 de Noviembre del 2003

Revisa la sintaxis de estos 2 comandos:

Para Guardar utiliza: COPY TO

Para Recuperar: APPEND FROM