como usar el CRVIEWER

D.MARADONA
27 de Marzo del 2004
hola como est谩n me pueden decir como se usa el CRviewer porque el problema es que no s茅 como puedo enlazarlo al reporte que voy a mostrar ni nada de eso.
por favor un sencillo c贸digo de ejemplo.

saludos
D.MARADONA

Bartolom
27 de Marzo del 2004
Primero, creo un formulario exclusivo para el reporte, supongamos que se llama formReporte, en el cual va a ir el objeto CrViewer. Luego, para llamarlo, lo hago desde un bot贸n ubicado en otro formulario cualquiera, con el siguiente evento:

Private Sub Bot贸n_Click()'Este bot贸n debe ir
'en otro form
Dim frmRep As New formReporte
frmRep.Show vbModal
Set frmRep = Nothing
End Sub


Luego en el formulario donde va el control CrViewer debes colocar lo siguiente:

Option Explicit
Private crApp As New CRAXDRT.Application
Private crReport As New CRAXDRT.Report

Private Sub Form_Load()
'Abrir el reporte
Screen.MousePointer = vbHourglass

Set crReport = crApp.OpenReport(App.Path & "tu reporte", 1)
'crReport.SQLQueryString = "Tu consulta SQL" ' esta
'consulta es opcional

CRViewer.ReportSource = crReport
CRViewer.DisplayGroupTree = False
CRViewer.ViewReport
Screen.MousePointer = vbDefault
End Sub

Private Sub Form_Resize()
CRViewer.Top = 0
CRViewer.Left = 0
CRViewer.Height = ScaleHeight
CRViewer.Width = ScaleWidth
End Sub

Private Sub Form_Unload(Cancel As Integer)
Set crReport = Nothing
Set crApp = Nothing
End Sub



Tambi茅n debes agregar la referencia (men煤 Proyecto, Referencias) el siguiente control:

Crystal Reports Active X Designer RunTime Library

Saludos!
Bartolom
Chile


Caz
27 de Marzo del 2004
Gracias por el ejemplo mi pana.....
era esto lo que necesitaba
ahora mi pregunta es a la hora de hacer el paquete de instalacion que Dll o componentes debo agregar....
Caz...!