Practicante
22 de Enero del 2005

Miren tengo el siguiente problema

realize una palicacion que por medio de una shell realiza un bcp para actualizar una base de datos Sybase
hasta aca todo esta bien
el problema q tengo es ahora
lo q pasa es q no puedo saber cuando termina de ejecutarse el shell por lo q como solucion creo un archivo texto de la operacion ...


lo que deseo hacer es poder abrir este archivo cuando se termine de crear ..

esto es lo q tengo hasta ahora


dlgOpenFile.FileName = pathfileout
If fso.FileExists(dlgOpenFile.FileName) = True Then
Kill dlgOpenFile.FileName
End If

'SetAttr dlgOpenFile.FileName, vbNormal


Dim fnum As Integer, bandera As Integer

DoEvents
script = "cmd /C ""bcp " & database & ".." & table & " in " & """" & pathfile _
& """" & " -U" & usr & " -P" & pwd & " -S" & server & " -c -t " & """" & ";" & """" & " > " & """" & pathfileout & """"""
x = Shell(script, vbNormalFocus)


fnum = FreeFile

bandera = 1

While bandera = 1
If fso.OpenTextFile(dlgOpenFile.FileName, 2, TristateFalse) Then
bandera = 0
End If
Wend
Open dlgOpenFile.FileName For Input As #fnum
Form4.txtFile.Visible = True
Form4.Label1.Caption = "Cargando TXT generado ...."
Form4.Label1.Visible = True
Call pausa
Form4.txtFile.text = Input$(LOF(fnum), fnum)
Form4.Label1.Visible = False

en?
22 de Enero del 2005

Determining the End of a Shelled Application Using GetExitCodeProcess:
http://vbnet.mvps.org/index.html?code/faq/getexitcprocess.htm

Determining the End of a Shelled Application Using WaitForSingleObject:
http://vbnet.mvps.org/index.html?code/faq/waitforsingleobject2.htm

Determining the End of a Shelled Application Using GetModuleUsage:
http://vbnet.mvps.org/index.html?code/faq/getmoduleusage.htm

__

l_island
22 de Enero del 2005

En lugar de utilizar Shell, mejor utiliza este c贸digo, el solito espera a que termine la ejecuci贸n de un programa antes de continuar en VB:

'make a batch file (.bat) in "c:" and name it "Test.bat", inside just
'write "pause". Your script will wait until you have pushed a button
'before ending. Now instead of the batch file, put the application you wish
'to run and you wish VB to wait for.

'Declarations:

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type
Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&


Private Sub Form_Load()
Dim retval as Long

retval = ExecCmd("c:test.bat")
End

End Sub


Public Function ExecCmd(cmdline$) As Long
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim ret as Long

start.cb = Len(start)
ret& = CreateProcessA(0&, cmdline$, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)

'Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function

Esto lo copie de alg煤n foro.

Saludos!!
l_island