walter
19 de Abril del 2005

alguien sabe como paso una fecha de fox que esta en ingles a español desde ya mil gracias

emilsonpineda
19 de Abril del 2005

mira estas son las funciones que utilizo yo en todos mis programas para manipular y mostrar la fecha:

*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver el nombre del mes en español.
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Lunes, 24 de Mayo del 2004
*!*
*!***********************************************************************************
function mes(nMonth)
if type("m.nMonth") != "N" then
m.nMonth = month(date())
endif
private aMonth
declare m.aMonth[12]
m.aMonth[1] = "Enero"
m.aMonth[2] = "Febrero"
m.aMonth[3] = "Marzo"
m.aMonth[4] = "Abril"
m.aMonth[5] = "Mayo"
m.aMonth[6] = "Junio"
m.aMonth[7] = "Julio"
m.aMonth[8] = "Agosto"
m.aMonth[9] = "Septiembre"
m.aMonth[10] = "Octubre"
m.aMonth[11] = "Noviembre"
m.aMonth[12] = "Diciembre"
return m.aMonth[m.nMonth]
endfunc


*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver el nombre del dia de la semana en español.
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Lunes, 24 de Mayo del 2004
*!*
*!***********************************************************************************
function dia(m.nDow)
if type("m.nDow") != "N" then
m.nDow = dow(date())
endif
private aDow
declare m.aDow[7]
m.aDow[1] = "Domingo"
m.aDow[2] = "Lunes"
m.aDow[3] = "Martes"
m.aDow[4] = "Miercoles"
m.aDow[5] = "Jueves"
m.aDow[6] = "Viernes"
m.aDow[7] = "Sábado"
return m.aDow[m.nDow]
endfunc


*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver la fecha con otro separador y en un formato de.:
*!* dd/mmm/yyyy, formato devuelto Caracter.
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Lunes, 24 de Mayo del 2004
*!*
*!***********************************************************************************
function fecha(dFecha,sSeparator)
DO CASE
CASE type("dFecha") = "L"
m.dFecha = date()
CASE TYPE("dFecha") = "C"
IF ISBLANK(m.dFecha) THEN
m.dFecha = DTOS(DATE())
ENDIF
m.dFecha = ;
CTOD(RIGHT(m.dFecha,2) + "/" + ;
SUBSTR(m.dFecha,5,2) + "/" + ;
LEFT(m.dFecha,4))
ENDCASE
if type("sSeparator") != "C" then
m.sSeparator = "."
endif
return transform(day(m.dFecha),"@L 99") + m.sSeparator + ;
upper(left(mes(month(m.dFecha)),3)) + m.sSeparator + ;
str(year(m.dFecha),4)
endfunc


*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver la fecha de un formato caracter (AAAAMMDD) a un
*!* formato date (dd/mm/aaaa)
*!* dd/mmm/yyyy, formato devuelto Caracter.
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Miercoles, 14 de Julio del 2004
*!*
*!***********************************************************************************
FUNCTION stod(sDate)
IF PCOUNT() = 0
RETURN {}
ENDIF
SET DATE TO DMY
RETURN CTOD(RIGHT(m.sDate,2)+"/"+SUBSTR(m.sDate,5,2)+"/"+LEFT(m.sDate,4))
ENDFUNC


*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver la hora en formato de 12
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Lunes, 24 de Mayo del 2004
*!*
*!***********************************************************************************
function hora(sTime)
local sRetVal
if type("m.sTime") != "C" then
m.sTime = time()
endif
if val(left(m.sTime,2)) > 12 then
m.sRetVal = transform(val(left(m.sTime,2))-12,"@L 99") + substr(m.sTime,3) + " pm"
else
if val(left(m.sTime,2)) = 12 then
m.sRetVal=m.sTime+" pm"
else
m.sRetVal=m.sTime+" am"
endif
endif
return m.sRetVal
endfunc


*!***********************************************************************************
*!*
*!* Funcion utilizada para devolver la fecha en formato largo
*!* Programador.: Marvin Emilson Pineda.
*!* Fecha.: Viernes, 18 de Junio del 2004
*!*
*!***********************************************************************************
FUNCTION hoy(uFecha)
PRIVATE sDate
STORE SET("date") TO m.sDate
SET DATE TO DMY
DO CASE
CASE TYPE("m.uFecha") = "L"
m.uFecha = DATE()
CASE TYPE("m.uFecha") = "C"
m.uFecha = ;
CTOD(RIGHT(m.uFecha,2) + "/" + ;
SUBSTR(m.uFecha,5,2) + "/" + ;
LEFT(m.uFecha,4))
ENDCASE
SET DATE TO (m.sDate)

RETURN dia(DOW(m.uFecha)) + ", " + ;
LTRIM(STR(DAY(m.uFecha))) + " de " + ;
mes(MONTH(m.uFecha)) + ' del ' + ;
STR(YEAR(m.uFecha),4)
ENDFUNC

Bien!, si te sirven

Manuel
19 de Abril del 2005

Completa los meses y los días y pon esto en un programa

LAFECHA=DATE()

MES1='ENERO'
MES2='FEBRERO'
MES3='MARZO'
MES4='ABRIL'
...
DIA1='DOMINGO'
DIA2='LUNES'
...

ELDIA='DIA'+ALLT(STR(DOW(LAFECHA)))
ELMES='MES'+ALLT(STR(MONT(LAFECHA)))
FECHAESP=&ELDIA+', '+ALLT(STR(DAY(LAFECHA)))+' DE '+&ELMES+' DE '+ALLT(STR(YEAR(LAFECHA)))
MESSAGEB(FECHAESP)