pepi79
23 de Mayo del 2004

Necesito que alguien me ayude porque cuando mando a imprimir unas facturas con mi programa en fox, la impresora Laser se pone en modo de que no tiene papel, luego de aprox. 30 segundos imprime una copia espera de nuevo e imprime la segunda, como puedo hacer para evitar esta demora?
desde ya muchas gracias a todos

lcuraca
23 de Mayo del 2004

te recomiendo que te bajes el service pack 5. del visual fox,
luis

Alejandro Guardini
23 de Mayo del 2004

*****************************************************************
* CLEARFRX.PRG
* Limpia informacion del tipo de impresora y su configuracion
* que es guardada al crear o modificar una report.
* Hay que limpiar estos datos para que pueda imprimirse en cualquier
* impresora dado que por ejemplo fue creada/modificada en una pc con
* impresora EPSON no "imprimiria correctamente" en clientes con HP.
******************************************************************
lnFiles=ADIR(frxArray,"*.FRX")
IF lnFiles = 0
WAIT WINDOW "No hay informes en "+curdir()
RETURN
ENDIF
lnCleaned=0
FOR I=1 TO ALEN(frxArray,1)
WAIT WINDOW "Limpiando "+frxArray[I,1] NOWAIT
USE (frxArray[I,1])
LOCATE
IF NOT EMPTY(TAG)
lnCleaned=lnCleaned+1
REPLA TAG WITH SPACE(0)
ENDIF
IF NOT EMPTY(TAG2)
REPLA TAG2 WITH SPACE(0)
ENDIF
IF NOT EMPTY(EXPR)
lEXPR =.F.
STORE MEMLINES(EXPR) TO gnNumLíneas
STORE 0 TO _MLINE && Restablece _MLINE a cero.
FOR count = 1 TO gnNumLíneas && Bucle para el número de líneas del campo memo.
lcLinea = MLINE(EXPR, 1, _MLINE)
lcDevice = "DEVICE="
IF lcDevice $ lcLinea
REPLA EXPR WITH STRTRAN(EXPR,lcLinea,lcDevice)
lEXPR =.T.
EXIT
ENDIF
NEXT
IF NOT lEXPR
REPLA EXPR WITH SPACE(0)
ENDIF
ENDIF
USE
ENDFOR
WAIT CLEAR
RELEASE ARRAY frxArray
IF lnCleaned > 0
WAIT WINDOW "Se limpiaron "+ALLTRIM(STR(lnCleaned))+" de "+ALLTRIM(STR(lnFiles))+" *.FRX"
ELSE
WAIT WINDOW "Las "+ALLTRIM(STR(lnFiles))+" Reports están limpias."
ENDIF