novato
14 de Octubre del 2005

Hola:
Si alguien me puede ayudar, necesito utilizar una toolbar que sea general para toda una aplicacion, pero por lo que se, no se puede insertar en un formulario, pero si se que se puede utilizar el screen de VFP para poder agregarla .
La pregunta es como hago para limpiar y configurar el escritorio de fox (6.0) para hacer correr ahi los demas formularios, el menu y la bendita toolbar.
De antemano GRACIAS

Andres
14 de Octubre del 2005

Crea normal tu projecto, un menu y agregale estas lineas dentro de un archivo prg. y listo.

PUBLIC tbrBarra
tbrBarra = CREATEOBJ('miToolbar')
tbrBarra.Dock(0)
tbrBarra.SHOW

DEFINE CLASS miToolbar AS Toolbar
ADD OBJECT lblUsr AS Label
ADD OBJECT sep1 AS Separator
ADD OBJECT cmdPrn AS CommandButton
ADD OBJECT sep2 AS Separator
ADD OBJECT cmdCalc AS CommandButton
ADD OBJECT sep3 AS Separator
ADD OBJECT cmdEmp AS CommandButton
ADD OBJECT sep4 AS Separator
ADD OBJECT cmdSalir AS CommandButton

cmdCalc.HEIGHT = 22
cmdCalc.WIDTH = 25
cmdCalc.Caption = ""
cmdCalc.Picture = CURDIR()+"calc.bmp"
cmdCalc.ToolTipText = "Calculadora"

cmdPrn.HEIGHT = 22
cmdPrn.WIDTH = 25
cmdPrn.Caption = ""
cmdPrn.Picture = CURDIR()+"print.bmp"
cmdPrn.ToolTipText = "Impresoras"

cmdSalir.HEIGHT = 22
cmdSalir.WIDTH = 25
cmdSalir.Caption = ""
cmdSalir.Picture = CURDIR()+"salir.bmp"
cmdSalir.ToolTipText = "Salir"

cmdEmp.HEIGHT = 22
cmdEmp.WIDTH = 25
cmdEmp.Caption = ""
cmdEmp.Picture = CURDIR()+"Present.bmp"
cmdEmp.ToolTipText = "Empresas"

lblUsr.HEIGHT = 22
lblUsr.WIDTH = 82
lblUsr.Caption = wUser
lblUsr.FontName = "Arial Narrow"
lblUsr.FontBold = .t.
lblUsr.FontSize = 10
lblUsr.ReadOnly = .t.
lblUsr.BorderStyle = 1
lblUsr.Alignment = 2
lblUsr.ToolTipText = "Usuario"

LEFT= 1
TOP = 1
AutoSize = .T.
CAPTION = "Prolim"

PROCEDURE cmdCalc.CLICK
Run /n Calc.exe
ENDPROC

PROCEDURE cmdPrn.CLICK
SET PRINTER TO NAME GETPRINTER( )
ENDPROC

PROCEDURE cmdEmp.CLICK
Do Form Empresas
ENDPROC

PROCEDURE cmdSalir.Click
_Screen.Picture=""
_Screen.Caption="Microsoft Visual Fox Pro"
tbrBarra.Hide
Set Sysmenu to defa
Set Message to
Close all
Clear Events
ENDPROC
ENDDEFINE

Suerte